Notify users to change their password before it get expired

Hi,
is there a script to check the password age for the user and send pop-up
message to him before his passwordget expired.
for example: i want a pop-up message to come to any user before 2 days from
his passoed expire date.

thanx

Bashar Badr wrote:

> Hi,
> is there a script to check the password age for the user and
> send pop-up message to him before his passwordget expired.
> for example: i want a pop-up message to come to any user before
> 2 days from his passoed expire date.
Hi

Assuming AD domain:

How Long Until My Password Expires?
http://msdn.microsoft.com/library/en...ng09102002.asp


Or using the PasswordLastChanged property:

'--------------------8<----------------------

Const SEC_IN_DAY = 86400
Const ADS_UF_PASSWD_CANT_CHANGE = &H40
Const ADS_UF_DONT_EXPIRE_PASSWD = &h10000

' Specify how many days before the dialog box will be shown
iExpireDayBeforePasswordExpireDialog = 2

Set oNetwork = CreateObject("Wscript.Network")
Set oADsSysInfo = CreateObject("ADSystemInfo")

sNetBIOSDomain = oNetwork.UserDomain

Set oDomainNT = GetObject("WinNT://" & sNetBIOSDomain)

'Get MaxPasswordAge from Active Directory
iMaxPwdAge = oDomainNT.Get("MaxPasswordAge")


' Retrieve password information for current user
sADsUser = oADsSysInfo.UserName

Set oUserLDAP = GetObject("LDAP://" & sADsUser)
lngFlag = oUserLDAP.Get("userAccountControl")
sPasswdLastChange = oUserLDAP.PasswordLastChanged

blnPwdExpire = True
If (lngFlag And ADS_UF_PASSWD_CANT_CHANGE) <> 0 Then
blnPwdExpire = False
End If
If (lngFlag And ADS_UF_DONT_EXPIRE_PASSWD) <> 0 Then
blnPwdExpire = False
End If

If blnPwdExpire = True Then
iMaxPasswdAgeValue = iMaxPwdAge / SEC_IN_DAY
'Calculate days to password expires
iDaysToPasswordExpires = Int((sPasswdLastChange + iMaxPasswdAgeValue) - Now)

If iDaysToPasswordExpires =< iExpireDayBeforePasswordExpireDialog Then
sInfoMessage = "Your Windows/Active Directory password will expire in " _
& iDaysToPasswordExpires & " day(s)."
'Display messagebox
MsgBox sInfoMessage, vbSystemModal+vbInformation, "Password Expire Check"
End If
End If

'--------------------8<----------------------


--
torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
Administration scripting examples and an ONLINE version of
the 1328 page Scripting Guide:
http://www.microsoft.com/technet/scr...r/default.mspx

I believe you can turn on password reminders in GP.

--
Jim Vierra

"Bashar Badr" <> wrote in message
news:598577A1-6A55-4FF7-8E4F-...
> Hi,
> is there a script to check the password age for the user and send pop-up
> message to him before his passwordget expired.
> for example: i want a pop-up message to come to any user before 2 days
> from
> his passoed expire date.
>
> thanx

That doesn't help users that only connect to a website such as Outlook Web
Access.

On Mon, 9 May 2005 11:33:57 -0400, "Jim Vierra" <> wrote:

>I believe you can turn on password reminders in GP.

Torgeir also sent you a script link. See his post at:
news:%...
--
Jim Vierra

"Corné Bogaarts" <> wrote in message
news:...
> That doesn't help users that only connect to a website such as Outlook Web
> Access.
>
> On Mon, 9 May 2005 11:33:57 -0400, "Jim Vierra" <> wrote:
>
>>I believe you can turn on password reminders in GP.
>

No he didn't, he sent it to Bashar Badr.
Please reply to the correct message in the thread. Especially since you don't
include the original message in your answers.

On Mon, 9 May 2005 17:16:10 -0400, "Jim Vierra" <> wrote:

>Torgeir also sent you a script link. See his post at:
>news:%...

Hey - I gave you a link to the exact message in my last post and it IS in
this thread.

Anyway - sorry if I confused you. It was my intention to be helpful.
--
Jim Vierra

"Corné Bogaarts" <> wrote in message
news:...
> No he didn't, he sent it to Bashar Badr.
> Please reply to the correct message in the thread. Especially since you
> don't
> include the original message in your answers.
>
> On Mon, 9 May 2005 17:16:10 -0400, "Jim Vierra" <> wrote:
>
>>Torgeir also sent you a script link. See his post at:
>>news:%.. .
>

Hi,
Also have a similar requirement.I visited the site u have given and tried
the code.I am working in asp.net . It is throwing some error. "Cannot create
ActiveX component"
Kindly tell me. Its very urgent

Regards
Finny

"Torgeir Bakken (MVP)" wrote:

> Bashar Badr wrote:
>
> > Hi,
> > is there a script to check the password age for the user and
> > send pop-up message to him before his passwordget expired.
> > for example: i want a pop-up message to come to any user before
> > 2 days from his passoed expire date.
> Hi
>
> Assuming AD domain:
>
> How Long Until My Password Expires?
> http://msdn.microsoft.com/library/en...ng09102002.asp
>
>
> Or using the PasswordLastChanged property:
>
> '--------------------8<----------------------
>
> Const SEC_IN_DAY = 86400
> Const ADS_UF_PASSWD_CANT_CHANGE = &H40
> Const ADS_UF_DONT_EXPIRE_PASSWD = &h10000
>
> ' Specify how many days before the dialog box will be shown
> iExpireDayBeforePasswordExpireDialog = 2
>
> Set oNetwork = CreateObject("Wscript.Network")
> Set oADsSysInfo = CreateObject("ADSystemInfo")
>
> sNetBIOSDomain = oNetwork.UserDomain
>
> Set oDomainNT = GetObject("WinNT://" & sNetBIOSDomain)
>
> 'Get MaxPasswordAge from Active Directory
> iMaxPwdAge = oDomainNT.Get("MaxPasswordAge")
>
>
> ' Retrieve password information for current user
> sADsUser = oADsSysInfo.UserName
>
> Set oUserLDAP = GetObject("LDAP://" & sADsUser)
> lngFlag = oUserLDAP.Get("userAccountControl")
> sPasswdLastChange = oUserLDAP.PasswordLastChanged
>
> blnPwdExpire = True
> If (lngFlag And ADS_UF_PASSWD_CANT_CHANGE) <> 0 Then
> blnPwdExpire = False
> End If
> If (lngFlag And ADS_UF_DONT_EXPIRE_PASSWD) <> 0 Then
> blnPwdExpire = False
> End If
>
> If blnPwdExpire = True Then
> iMaxPasswdAgeValue = iMaxPwdAge / SEC_IN_DAY
> 'Calculate days to password expires
> iDaysToPasswordExpires = Int((sPasswdLastChange + iMaxPasswdAgeValue) - Now)
>
> If iDaysToPasswordExpires =< iExpireDayBeforePasswordExpireDialog Then
> sInfoMessage = "Your Windows/Active Directory password will expire in " _
> & iDaysToPasswordExpires & " day(s)."
> 'Display messagebox
> MsgBox sInfoMessage, vbSystemModal+vbInformation, "Password Expire Check"
> End If
> End If
>
> '--------------------8<----------------------
>
>
> --
> torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
> Administration scripting examples and an ONLINE version of
> the 1328 page Scripting Guide:
> http://www.microsoft.com/technet/scr...r/default.mspx
>

We use Netwrix password expiration notifier. It sends reports that warn users of expirations so they can change their passwords before they expire.Password Expiration Notifier (Freeware Edition)