Need to create and print a Software Inventory

It has become necessary for me to re-install MS XP Entertainment. Before I
undertake this task I'd like to create and print a list of all the software
on my computer. How can I easily do this? Is there software or a utility
which might facilitate this task?

 

create a new text file on your desktop and name it installedApps.txt. Open
the file in Notepad and copy and paste the code below. after you have copied
and pasted the code rename the file so the the .txt extension is replaced
with a .vbs extension and the icon looks like a little scroll page. double
click the file to run the script and you should be able to open a text file
called apps.txt in your C drive. from there you can print the text file:
------Code Block-------

Const OpenAsASCII = 0 ' Opens the file as ASCII (TristateFalse)
Const OverwriteIfExist = -1

' file where result is to be saved
sFile = "c:\apps.txt"

sComputer = "." ' use . for local computer

Set oFSO = CreateObject("Scripting.FileSystemObject")
Set fFile = oFSO.CreateTextFile(sFile, _
OverwriteIfExist, OpenAsASCII)

fFile.Write InstalledApplications(sComputer)
fFile.Close

Function InstalledApplications(node)
Const HKLM = &H80000002 'HKEY_LOCAL_MACHINE
Set oRegistry = _
GetObject("winmgmts:{impersonationLevel=impersonate}!\\" _
& node & "/root/default:StdRegProv")
sBaseKey = _
"SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\"
iRC = oRegistry.EnumKey(HKLM, sBaseKey, arSubKeys)
For Each sKey In arSubKeys
iRC = oRegistry.GetStringValue( _
HKLM, sBaseKey & sKey, "DisplayName", sValue)
If iRC <> 0 Then
oRegistry.GetStringValue _
HKLM, sBaseKey & sKey, "QuietDisplayName", sValue
End If
If sValue <> "" Then
InstalledApplications = _
InstalledApplications & sValue & vbCrLf
End If
Next
End Function

-------End Code Block------
let me know if that works for you.

b

 

It WORKS! Thank you, I really do appreciate your help.

 

Try Belarc Advisor...it's free
http://www.belarc.com/free_download.html

 

no prob, here's where i found it:
http://groups.google.com/group/microsoft.public.scripting.vbscript/msg/61ab783b95da111a